Lunes anterior y Domingos anteriores fecha basada en la fecha de hoy

En lugar de usar una opción de caso, también podría hacer esto para obtener el domingo de la semana actual:

SELECT DATEADD(dd, DATEPART(DW,GETDATE())*-1+1, GETDATE())

Para obtener el domingo de la semana anterior, reste 7 días más:

SELECT DATEADD(dd, DATEPART(DW,GETDATE())*-1-6, GETDATE())

Creo que esta es una solución mucho más limpia:

SELECT
    -- 17530101 or 1753-01-01 is the minimum date in SQL Server
    DATEADD(dd, ((DATEDIFF(dd, '17530101', GETDATE()) / 7) * 7) - 7, '17530101') AS [LowerLimit], -- Last Week's Monday
    DATEADD(dd, ((DATEDIFF(dd, '17530101', GETDATE()) / 7) * 7) - 1, '17530101') AS [UpperLimit] -- Last Week's Sunday.

Que se puede usar así en una consulta del mundo real:

SELECT
    *
FROM
    SomeTable
WHERE
    SomeTable.[Date] >= DATEADD(dd, ((DATEDIFF(dd, '17530101', GETDATE()) / 7) * 7) - 7, '17530101') AND
    SomeTable.[Date] <= DATEADD(dd, ((DATEDIFF(dd, '17530101', GETDATE()) / 7) * 7) - 1, '17530101')

Aquí hay algunas pruebas:

1. Año Bisiesto

Fecha Actual: 2016-02-29 00:00:00.000

Resultados:

LowerLimit                 UpperLimit
2016-02-22 00:00:00.000    2016-02-28 00:00:00.000

2. La semana pasada fue en año diferente

Fecha Actual: 2016-01-06 00:00:00.000

LowerLimit                 UpperLimit
2015-12-28 00:00:00.000    2016-01-03 00:00:00.000

3. Límite inferior del mes anterior y límite superior del mes en curso

Fecha Actual: 2016-05-04 00:00:00.000

LowerLimit                 UpperLimit
2016-04-25 00:00:00.000    2016-05-01 00:00:00.000

4. La fecha actual es Domingo

Fecha Actual: 2016-05-08 00:00:00.000

LowerLimit                 UpperLimit
2016-04-25 00:00:00.000    2016-05-01 00:00:00.000

Aún mejor, creo, esto funciona para cualquier fecha, cualquier día de la semana, con cualquier parámetro DateFirst (establecer el primer día de la semana, generalmente 1-Lunes en Francia, por defecto es 7-Domingo).

create function [dbo].[previousWeekDayDate](@anyDate date, @anyWeekDay int)
returns Date
as
begin
    return DATEADD(dd, ((DATEPART(dw,@anyDate) + @@DateFirst - @anyWeekDay + 13) % 7) * -1, @anyDate)
end

Funciona para SQL 2008, cree la función y use:

SELECT dbo.previousWeekDayDate(GetDate(),1) --for Monday
SELECT dbo.previousWeekDayDate(GetDate(),7) --for Sunday

Cabe señalar que el problema con los domingos parece ya no estar presente al menos a partir de MSSQL 2012. Tanto la solución simple

SELECT DATEADD(wk, DATEDIFF(wk, 6, @input), 0)

Y el complejo

SELECT DATEADD(wk, DATEDIFF(wk, 6, 
CASE DATEPART(dw,@input)
WHEN 1 THEN DATEADD(d,-1,@input)
ELSE @input
END
), 0)

Devuelve lo mismo para cualquier fecha que haya probado, incluidos los domingos.